We will proceed to deposit the SIM card correctly to the PLC. To do this, you must first locate the SIM card entry of the PLC, which is located on the top cover of the device. You will be able to see the symbol for the SIM card on the screen printing; the entrance is just below. To enter the card, you must do it as shown in the following images:

2. Software configuration

We have to follow these points to ensure the correct behavior of the GPRS:

    1.- Select the right family and model of the Boards (the GPRS family and model that you have)

GPRS

    2.- Be sure to import the GPRS.h header, which is included in our Boards and was developed by our programmers:

#include <GPRS.h>

 Here you have a post about how to install our Boards:

•     Installing the Industrial Shields Boards in the Arduino IDE (Updated)

    3.-It is very important to implement certain functions like the one used for enabling the module if they are needed in your program:

GPRS.enableGPRS(APN, USERNAME, PASSWORD)

If you want to see all the GPRS functions available, you can check the proper documentation when you download the Boards.

First of all, you have to define the parameters of your SIM card (PIN, APN, USERNAME, PASSWORD). They depend on the phone company of the card, you can find them on the Internet or contact directly the company if you do not have them. This program is a simple example of an HTTP client. In the setup block, it looks if a PIN number is required and, if it is, it checks if it is correct and unlocks the SIM. In the loop block, the program executes every 2 seconds the following parameters; it checks if the NetworkStatus is 1 (Registered(home)) or 5 (Registered(roaming)), if it is one of these, it proceeds to check the GPRSstatus if it is 1 (GPRS connected) it checks if the client is connected and send some messages to the server. After this, if the client is available, the program writes the previous messages in the Serial Port (Serial Monitor) to check them all.

Here you have the code:

// GPRS library example
// by Industrial Shields

#include <GPRS.h>

#define PIN ""
#define APN ""
#define USERNAME ""
#define PASSWORD ""

GPRSClient client;
uint8_t buffer[1024];

////////////////////////////////////////////////////////////////////////////////////////////////////

void setup() {
  Serial.begin(9600UL);

  if (!GPRS.begin()) {
    Serial.println("Impossible to begin GPRS");
    while(true);
  }

  int pinRequired = GPRS.isPINRequired();
  if (pinRequired == 1) {
    if (!GPRS.unlockSIM(PIN)) {
      Serial.println("Invalid PIN");
      while (true);
    }
  }
  else if (pinRequired != 0) {
    Serial.println("Blocked SIM");
    while (true);
  }
}

////////////////////////////////////////////////////////////////////////////////////////////////////

void loop() {
  static uint32_t lastStatusTime = millis();
  if (millis() - lastStatusTime > 2000) {
    uint8_t networkStatus = GPRS.getNetworkStatus();
    Serial.print("Status: ");
    Serial.println(networkStatus);
    lastStatusTime = millis();

    if ((networkStatus == 1) || (networkStatus == 5)) {
      int GPRSStatus = GPRS.getGPRSStatus();
      if (GPRSStatus == 0) {
        if (!GPRS.enableGPRS(APN, USERNAME, PASSWORD)) {
          Serial.println("GPRS not enabled");
        }
      } 
      else if (GPRSStatus == 1) {
        if (GPRS.connected()) {
          if (!client.connected()) {
            static bool requestDone = false;
            if (!requestDone) {
              if (!client.connect("www.industrialshields.com", 80)) {
                Serial.println("Error connecting to web");
              } 
              else {
                client.println("GET /index.html HTTP/1.1");
                client.println("Host: www.industrialshields.com");
                client.println("User-Agent: GPRS-PLC");
                client.println();
                Serial.println("Connected");
                Serial.println("Data sent");
                requestDone = true;
              }
            }
          } 
          else if (client.available()) {
            Serial.println("HTTP response:");
            size_t len = client.read(buffer, sizeof(buffer));
            Serial.write(buffer, len);
            client.stop();
          }
        }
      }
    }
  }
}